Text 68, 173 rader
Skriven 2004-10-21 05:52:55 av Gerald Miller (1:342/512)
     Kommentar till text 65 av BEN RITCHEY (1:393/68)
Ärende: Looking for a file in an archive
========================================
Hello BEN,

    Responding to a post in the BATPOWER area:
    On Wednesday October 20 2004 at 22:01,
    BEN RITCHEY [1:393/68] wrote to GERALD MILLER,
    about: Re: Looking for a file in an archive

 | GM>>>> tell me which BFDS archive contains: REMVCRLF.COM
 BR>>> None of them <g> but plenty of CRLF utilities. What do you need?
 | GM>> I'm trying to find a DOS utility that will remove the Carriage
 | GM>> Returns and Line Feeds.....
 | GM>> Could you point me to a source that has a DOS binary that will
 | GM>> remove the CRs LFs or send such to the Addison Kimmel email
 | GM>> address?

 BR> Check your E-mail. I sent you Bruce Guthrie's CHANGE utility that I
 BR> use daily (his page is at http://users.erols.com/waynesof/bruce.htm).

I received it just fine; thanks Ben.

 BR> Just specify "CHANGE.EXE <filename> /FROM &H0D0A /TO NULL"

 BR> Of course you *may* want to change each occurance TO space (&H20) so
 BR> the lines won't run together (?). Keep some backup just in case <g>.

I will look into making modifications to the ALL.INI (the initialization
file for all the Bruce Guthrie programs that I use on this system) under
the [CHANGE] header...

I guess that I had change (although it was an older version) all along --
that's the problem with having so much stuff on all the hard drives,
especially when they are inadequately described...  <grin>

 BR> What program extracts FILE_ID.DIZ and builds the DESCRIPT.ION files? I
 BR> definitely want that one, if I don't already have it. :-)

It's not a program, per say (well, it's a 4DOS BTM file)...

I'm not nearly ready to post / release the BTM because I'm still "bumbling"
my way through it, seeing what works and what doesn't.  I had asked )\/(ark
Lewis for some assistance in the 4DOS echo area, but I imagine he's
extremely busy...

I will post the copy of the Barry Block message that I had made reference
to:

=== Cut Begin: DIZ2DES.BTM ===
::  = [0] 4DOS Support Echo ======================================== 4DOS =
::   Msg  : 526 of 527 -499
::   From : Barry Block                 2:280/901.42    20 May 98  22:57:24
::   To   : John Hentsch                                23 May 98  09:09:56
::   Subj : CLI solutions to LFN problems
::  =======================================================================
::   JH> What I want to do is something like:
::   JH> 1. Check the archive library directories for any compressed file
::   JH> (zip rar lha ect) that doesn't have a description.
::   JH> 2. If it doesn't, check to see if there is a DIZ or SDI file in
::   JH> it. If there is, import the DZI or SDI as the DESCRIPTION for
::   JH> 4DOS.
::   JH> Anyone seen a 4DOS routine already written to such a task that I
::   JH> could adapt for my use?
::
::  You might check this out for ideas. I call it Diz2Des.btm. I also have
::  the opposite one, etc.
::

@*echo off
setdos/x-1 %+ setlocal %+ unset * %+ cls
  if %@index[   /? -? , %& ] NE -1 goto ?

::  <<--- INSTALL YOUR EDITOR HERE ---
SET E=c:\qe3\QEDIT.EXE  %+

::  <<--- CHANGE THE TEMPFILE DIRECTORY AS YOU WISH
SET Tmp_Dir=G:\      %+

::  <<--- DIR('s) WHERE GUS.EXE, ARCHIVERS, & REMVCRLF.COM RESIDE
SET PATH=C:\Shz      %+

if not exist %@search[GUS.EXE] (echo Program  GUS.EXE  not found. %+ goto ?)
if not exist %@search[REMVCRLF.COM] (echo Program  REMVCRLF.COM  not%=
found. %+ goto ?)
on errormsg pause %+ on break goto q

iff exist %Tmp_Dir%FILE_ID.DIZ  then
    set tmpfile=%@unique[%Tmp_Dir]
    move/q %Tmp_Dir%FILE_ID.DIZ %tmpfile
    if %_? ne 0 (echo Could not move the file  %Tmp_Dir%FILE_ID.DIZ %+ goto q)
    endiff

iff %1 ne * .and. exist %1 then %+
    for %f in (%1) gosub proceed
  elseiff "%1"=="*" .or. "%1"=="/E" then %+
    for %f in (*.ARC;*.ARJ;*.DWC;*.HA;*.HAP;*.HPK;*.HYP;*.LZH;*.PAK;*.RAR;%=
*.SQZ;*.UC2;*.ZIP;*.ZOO) gosub proceed
  else
    echo %@Name[%0].BTM Aborting - %@if[%1~=~,FileSpec required,File(s) %1 %=
not found.]
  endiff

:exit
if exist %tmpfile move/q %tmpfile %Tmp_Dir%FILE_ID.DIZ
goto q

:proceed
GUS %f file_id.diz %Tmp_Dir /q /n /r >& nul
echo. %+  echos %f` `
iff %? ne 0 then
       screen +0 13 --- GUS processing unsuccessful. (File_id.diz not %=
found?)%=n
       return
  else screen +0 13 --- GUS extracted file_id.diz` `
  endiff

attrib/q -r-h %Tmp_Dir%FILE_ID.DIZ

iff %@index[%&,/e] ne -1 then
    iff not exist %@search[%e] then
        echo. %+ echo Text Editor (line 3) not found. %+ beep
        goto ?
    else %e %Tmp_Dir%FILE_ID.DIZ
        screen +1 0
    endiff
  endiff

REMVCRLF.COM %Tmp_Dir%FILE_ID.DIZ
if %? ne 0 goto del_diz

describe %f < %Tmp_Dir%FILE_ID.DIZ
if %_?=0 screen +0 43 --- Description completed

:del_diz
del/q %Tmp_Dir`file_id.diz`
if %?=6 (echo The File_id.diz was useless. %+ beep 100 4 65 3)
return

:?
text

          +=============================================================+
          | Diz2Des v7 - 4DOS .BTM that will extract the FILE_ID.DIZ    |
          | from an archive file and use it as the file's description   |
          | If /E option is used, your text editor is called. (line 24) |
          | The programs GUS.EXE, REMVCRLF.COM and archivers called     |
          | must be in the local path (line 30). Set Tmp_Dir on line 27 |
          |                                                             |
          | Usage: Diz2Des [filename.ext] [/E] [/?]     Wildcards ok    |
          +=============================================================+
endtext
delay 10
::Barry Block  7-96  2:280/901.42   Barry_Block@p42.f901.n280.z2.fidonet.org

:q
setdos/x+1
=== Cut End:   DIZ2DES.BTM ===

Hopefully the BTM lines are not truncated and I expect the 4DOS "%=" to
work as described in the documentation -- it means that everything on the
next line _should_ be wrapped up to that line (does that make sense?)

I will change every occurrence of REMVCRLF.COM to CHANGE.EXE and see if the
above BTM will work or what CHANGEs (couldn't help myself :) are required.

Ideally, the BTM would test for the %COMSPEC and if it should be
COMMAND.COM, then the BTM (BATch) would jump to a section where it would do
(essentially) the same tasks under the command.com processor, but the above
BTM is what I wanted to try...

           Cheers ... Gerald

... Have you ever imagined a world with no hypothetical situations?
--- GoldED+/DPMI32 v1.1.5-040330
 * Origin: Are Adric and Wesley Crusher really brothers? (1:342/512)